home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Micro on the Apple Volume 2 (1981)(Micro Ink).zip / Micro on the Apple Volume 2 (1981)(Micro Ink).do / BINARY TRANSFER.bas < prev    next >
BASIC Source File  |  1996-12-24  |  3KB  |  61 lines
  1. 1  REM  ************************
  2. 2  REM  *                      *
  3. 3  REM  * MICROMODEM TRANSFERS *
  4. 4  REM  *   GEORGE DOMBROWSKI  *
  5. 5  REM  *                      *
  6. 6  REM  *    BINARY TRANSFER   *
  7. 7  REM  *                      *
  8. 8  REM  *  COPYRIGHT (C) 1981  *
  9. 9  REM  *    MICRO INK, INC.   *
  10. 10  REM * CHELMSFORD, MA 01824 *
  11. 11  REM *  ALL RIGHTS RESERVED *
  12. 12  REM *                      *
  13. 13  REM ************************
  14. 14  REM 
  15. 15  REM 
  16. 19  REM  BINARY TRANSFER/MICROMODEM II
  17. 20 D$ =  CHR$(4)
  18. 30  PRINT D$"NOMON C,I,O"
  19. 40  GOSUB 420
  20. 50  INPUT "IS RECEIVING COMPUTER IN REMOTE MODE WITH EITHER BASIC INITIALIZED?";ANS$
  21. 60  PRINT 
  22. 70  IF  LEFT$(ANS$,1) < >"Y"  THEN  PRINT "TRANSFER ADANDONED": END 
  23. 80  POKE 1530,60: POKE 1914,18: REM  600 MSEC WAIT AFTER CARRIAGE RETURN.AUTO LINE FEED IS ACIVATED AND THE WAIT FUNCTION + LOCAL DISPLAY ENABLED.
  24. 90  PRINT "STARTING ADDRESS-": INPUT "(MUST END WITH 0 OR 8)";ST$
  25. 100  REM  LINES 110/170 - HEXIDECIMAL TO DECIMAL CONVERSION.
  26. 110 Z$ = "0123456789ABCDEF"
  27. 120  FOR I =  LEN(ST$) TO 1  STEP  -1
  28. 130  FOR J = 1 TO  LEN(Z$)
  29. 140  IF  MID$ (Z$,J,1) < > MID$ (ST$,I,1)  THEN  NEXT J
  30. 150 DEC = DEC +(J -1) *(16 ^X)
  31. 160 X = X +1: NEXT I
  32. 170 HB =  INT(DEC/256):LB = DEC -(HB *256)
  33. 180  REM  LINE 190 PLACES THE DECIMAL EQUIVALENTS OF THE HIGH & LOW BYTE ADDRESS INTO THE PAGE 0 LOCATIONS USED BY THE MEMORY DUMP ROUTINE.
  34. 190  POKE 61,HB: POKE 60,LB
  35. 200  INPUT "NUMBER OF BYTES (DECIMAL) ";NB
  36. 210  PRINT : INVERSE : HTAB 6: PRINT "HITTING ANY KEY ABORTS TRANSFER": NORMAL 
  37. 220  PRINT D$"IN #0"
  38. 230  PRINT D$"PR #2"
  39. 240  PRINT "CALL-151"
  40. 250  PRINT : REM  SENDS CARRIAGE RETURN.
  41. 260  FOR I = 1 TO  INT(NB/8) +1
  42. 270  IF  PEEK( -16384) >127  THEN  POKE  -16368,0: GOTO 300
  43. 280  CALL 4113: REM  CALLS MACHINE LANGUAGE ROUTINE BELOW.
  44. 290  NEXT I
  45. 300  PRINT 
  46. 310  PRINT "3DOG"
  47. 320  PRINT D$"PR #0"
  48. 330  PRINT 
  49. 340  POKE 1530,3: REM  NORMAL 30 MSEC WAIT
  50. 350  PRINT "           *** ALL DONE ***"
  51. 360  PRINT : PRINT "THE SENDING COMPUTERIS NOW IN TERMINAL MODE & THE RECEIVING COMPUTER HAS BEEN RETURNED WITH BASIC UP IN REMOTE MODE."
  52. 370  PRINT : INVERSE : HTAB 15: PRINT "HIT RETURN": NORMAL 
  53. 380  PRINT D$"IN #2"
  54. 390  POKE 1914,138: REM  INITIATE TEMINAL MODE/FULL-DUPLEX (USE 10 FOR   HALF-DUPLEX).
  55. 400  END 
  56. 410  REM  LINES 420/450 LOAD RELOCATED MEMORY DUMP ROUTINE AT $1000.
  57. 420  FOR M = 4096 TO 4147: READ D: POKE M,D: NEXT M
  58. 430  RETURN 
  59. 440  DATA  164,61,166,60,32,142,253,32,64,249,160,0,169,186,76,237,253,165,60,9,7,133,62,165,61,133,63,165,60,41,7,208,3,32,0,16
  60. 450  DATA  169,160,32,237,253,177,60,32,218,253,32,186,252,144,232,96
  61. 460  REM   THE BASIC PRGM + DUMP ROUTINE OCCUPY $800-$1040. IF THE BINARYDATA TO BE SENT RESIDES IN THIS RANGE, IT MUST FIRST BE RELOCATED  WITH THE MONITOR MOVE COMMAND.